[经验] 【转载】Multi-Touch with CapTIvate

maylove 2016-9-14 15:45 楼主

Use CapTIvate technology for multi-touch with 64 pads!

这个项目中使用的东西THINGS USED IN THIS PROJECTHardware components:

Texas Instruments MSP430 Microcontroller

Texas Instruments CapTIvate MCU Development Kit

Software apps and online services:

TI LaunchPad Energia

Texas Instruments Code Composer Studio

[tr][/tr]

Texas Instruments CapTIvate Design Center GUI查看详情

STORY

This project uses the CapTIvate MCU Development Kit as a BoosterPack and displays the pads on the Kentec 3.5" SPI screen.

The idea is to design a generic capacitive board I could use with different projects, like a board with 8 x 8 pads for a calculator.

This project shows an example of a programmable sensor.

Step 0: Hardware and Software

Hardware includes (external links)

MSP432 LaunchPad

Kentec 3.5" SPI BoosterPack

CapTIvate MCU Development Kit,

and optionally a custom capacitive board.

回复评论（3）

沙发 maylove

Software is available on Windows, Linux and macOS (external links)

CapTIvate Design Center GUI

Code Composer Studio

Energia 1.6.11E18

Step 1: Prepare the Hardware

To turn the board with the MSP430FR2633 MCU into a BoosterPack, we are going to use the holes the board provisions for the extended 40-pin BoosterPack.

However, the MSP430FR2633 board only uses 20 pins, so we solder those 20 pins only.

The CapTIvate board rises an interrupt on pin 8 and sends the messages in bulk, through either the UART port (pins 3 and 4) or the I2C port (pins 9 and 10).

This project uses the I2C port, so we remove the jumpers for UART, TXD/P1.4and RXD/P1.5.

This frees the UART port on the LaunchPad (pins 3 and 4) for the serial console.

Step 2: Configure the BoosterPack

We're going to use CapTIvate Design Center GUI, available for Windows, Linux and macOS, to

Design the capacitive board

Configure the MSP430FR2633

Generate the code

Configuring a capacitive board is very easy thanks to the automatic options, one for assigning the I/O and another for generating the code.

Let's work with CapTIvate Design Center GUI:

Open the CapTIvate Design Center GUI

Call the menu File > Project New to create a new project, name it,

Drag and drop a controller and a button group from the tool bar to the working space

Double click on the button group to open the Button Sensor Properties window

Set Element group to 64

Close the Button Sensor Properties window
Double click on the controller to open the Controller Properties window,
- Select MSP430FR2633 IRHB as Device
- Click on Auto-Assign or assign the Unconnected electrodes to the Sensors BTN00 manually
- Check the OK label is green
- Click on Generate Code Source
- Close the Controller Properties window
- Call the menu File > Project Save to save the project
[url=] [/url]

[url=]Referring to the schematics helps and improves the assignation of the elements to the TX and RX ports. [/url]
[url=] [/url]
[url=]
Let's work with Code Composer Studio:
- Open Code Composer Studio
- Call the menu Project > Import CCS Project and select the project generated previously
- Click on the hammer icon or call the menu Project > Build Project to build the project
[/url]

点赞 2016-9-14 15:53

板凳 maylove

Prepare the hardware by assembling the different boards together, from left to right:

the capacitive board

the CapTIvate BoosterPack

the programmer board

Then connect the programmer board to the USB port of the computer Back to Code Composer Studio,
- Click on the bug icon or call the menu Run > Debug to upload the program to the MSP430FR2633 and launch the debugger.
- Click on the red square to end the session
- To check every works fine,
  - Return to CapTIvate Design Center GUI
  - Call the menu Communication > Connect
  - Move one finger on the capacitive board
  The screen shows the pads with proximity in orange and the pads with touch in green.
- Step 3: Program the LaunchPad
  I'm using the MSP432 LaunchPad using Energia 1.6.10E18. Energia is based on the Arduino / Wiring framework.
  The project calls three libraries:
  - the Wire library for the I2C protocol to communicate with the CapTIvate BoossterPack,
  - the SPI library for the SPI protocol to communicate with the Kentec screen BoosterPack,
  - the Screen_K35_SPI library for the Kentec 3.5" SPI screen is bundled with Energia.
  3.1 Data Acquisition
  One single function getCapTIvate64() acquires and processes the data from the BoosterPack.
  The function isSomething() returns true if there is at least one pad with proximity or touch.
  There are five kinds of messages called packets but our project only uses the Cycle Packet, which eases reading and decoding.Remember, the capacitive board has been configured with 1 sensor, 16 cycles of 4 elements each, for a grand total of 64 pads.
- A message includes
  - one preliminary byte with the length of the message,
  - byte 0 is the Command Byte, always 0 for Cycle Packet,
  - byte 1 is the Sensor ID Byte, always 0 in the project,
  - byte 2 is the Cycle ID Byte, 0~15 in the project,
  - bytes 3 to 5 are the Cycle State Bytes with, the first 12 bits (MSB) for proximity and the last 12 bits (LSB) for touch, one bit per element of the cycle.
  - the remaining bytes of the message (except the last 2) are the Element LTA and Element Count Bytes, 4 bytes by element and 4 elements, with details (long term average and count) for each element of the cycle,
  - the last two bytes of the message for the 16-bit checksum (CRC).
  Texas Instruments provides all the information needed with the Technology Guide.
- A logic analyser was very helpful for decoding the I2C messages! pan>
- 3.2 Screen Management
  The two functions prepareScreen() and refreshScreen() manage the screen. To speed up display, only modified areas are updated.
  The screen is refreshed only
  - after the 16 cycles have been completed, and
  - if there are pads with proximity and pads with touch.
  The screen shows the pads with proximity in orange and the pads with touch in green.
- Step 4: Build and Run the Program
  Let's work with Energia!
  - Open Energia,
  - Call the menu File > Open and select the sketch CapTIvate_64.ino,
  - Click on the check icon or call the menu Sketch > Verify/Compile to compile the sketch,
  - Prepare the hardware by assembling the different boards together, from bottom to top:
    - the CapTIvate BoosterPack connected to the capacitive board,
    - the MSP432 LaunchPad,
    - the Kentec 3.5" SPI screen.
    - Then connect the MSP432 LaunchPad to the USB port of the computer.
    - Back to Energia,
      - Click on the arrow icon or call the menu Project > Upload to upload the binary to the MSP432 LaunchPad.
      - Move one finger on the capacitive board.
      Multiple areas are displayed on the screen as CapTIvate tracks multi-touch.
      The screen shows the pads with proximity in orange and the pads with touch in green.
      Optionally, you can use Code Composer Studio instead of Energia.
      - Open Code Composer Studio,
      - Call the menu Project > Import Energia Project and select the sketch CapTIvate_64.ino,
      - Proceed as previously, build and upload.
      - On the picture below, I put my left hand on the capacitive board: the board detected 8 pads with touch and 7 pads with proximity.

点赞 2016-9-14 15:59

4楼 maylove

Conclusion

The CapTIvate is very efficient in sorting signal from noise, and touch from proximity.

CODE

///
/// @file CapTIvate_public.ino
/// [url=home.php?mod=space&uid=159083]@brief[/url] Main sketch
///
/// @details CapTIvate project for Hackster.io
/// @n [url=home.php?mod=space&uid=40190]@a[/url] Developed with [embedXcode+](http://embedXcode.weebly.com)
///
/// @author Rei Vilo
/// @author http://www.embeddedcomputing.weebly.com
/// [url=home.php?mod=space&uid=311857]@date[/url] Jul 17, 2016
/// [url=home.php?mod=space&uid=252314]@version[/url] 101
///
/// @copyright CC = BY SA NC
///
/// @see ReadMe.txt for references
/// @n
///
// Core library for code-sense - IDE-based
#include "Energia.h"
// Set parameters
#define I2C_SLAVE 0x0a
#define pinIRQ 8
#define pinSingleTouch 11
#define pinMultipleTouch 12
// Include application, user and local libraries
#include "Wire.h"
#include "SPI.h"
#include "Screen_K35_SPI.h"
Screen_K35_SPI myScreen;
// Define structures and classes
struct element_t
{
uint16_t LTAValue; // long term average
uint16_t countValue;
};
struct packetCycle_t
{
uint8_t byteCommand;
uint8_t byteSensorID;
uint8_t byteCycleID;
uint16_t bitsCycleTouchState;
uint16_t bitsCycleProximityState;
uint32_t bitsCycleState;
uint8_t numberElements;
element_t element[12];
uint16_t packetChecksum;
};
enum state_t
{
stateNone,
stateProximity,
stateTouch
};
// Define variables and constants
uint8_t buffer[54];
packetCycle_t packetCycle;
uint8_t numberBytes;
state_t table[8][8] = { stateNone };
state_t oldTable[8][8] = { stateNone };
uint8_t x, y;
uint8_t countTouch = 0;
uint8_t countProximity = 0;
String text;
// Prototypes
bool isSomething();
void getCapTIvate64();
void prepareScreen();
void refreshScreen();
// Functions
bool isSomething()
{
return (countProximity + countTouch > 0);
}
void getCapTIvate64()
{
uint16_t calculatedChecksum = 0;
bool flagComplete = false;
uint16_t cycles = 0;
// Initialise scan
memset(table, stateNone, sizeof(table));
countTouch = 0;
countProximity = 0;
// Perform scan
while (!flagComplete)
{
if (digitalRead(pinIRQ))
{
packetCycle.numberElements = (numberBytes - 8) / 4;
Wire.requestFrom(I2C_SLAVE, 48);
numberBytes = Wire.read();
calculatedChecksum = 0;
for (uint8_t i = 0; i < numberBytes; i++)
{
buffer[i] = Wire.read();
if (i < numberBytes - 2)
{
calculatedChecksum += buffer[i];
}
}
// Scan cycles management
packetCycle.byteCycleID = buffer[2];
bitSet(cycles, packetCycle.byteCycleID);
flagComplete = (cycles == 0xffff);
packetCycle.packetChecksum = buffer[numberBytes - 2] + buffer[numberBytes - 1] * 256;
if (calculatedChecksum == packetCycle.packetChecksum) // Is checksum correct?
{
// Command byte
packetCycle.byteCommand = buffer[0];
// Is packet and is there some proximity or touch state?
if ((packetCycle.byteCommand == 0x01) and (buffer[3] or buffer[4] or buffer[5]))
{
packetCycle.numberElements = (numberBytes - 8) / 4; // 4 bytes per element
packetCycle.byteSensorID = buffer[1];
packetCycle.byteCycleID = buffer[2];
packetCycle.bitsCycleState = (uint32_t)((buffer[5] << 16) + (buffer[4] << 8) + buffer[3]);
for (uint8_t elementID = 0; elementID < packetCycle.numberElements; elementID++)
{
x = 2 * elementID + (packetCycle.byteCycleID % 2);
y = packetCycle.byteCycleID / 2;
if (bitRead(packetCycle.bitsCycleState, (elementID)))
{
if (table[x][y] != stateTouch)
{
table[x][y] = stateProximity;
countProximity += 1;
}
}
if (bitRead(packetCycle.bitsCycleState, (12 + elementID)))
{
table[x][y] = stateTouch;
countTouch += 1;
}
}
}
}
}
}
}
void prepareScreen()
{
myScreen.begin();
myScreen.setOrientation(0);
myScreen.setFontSize(0);
myScreen.gText(0, myScreen.screenSizeY() - 2 * myScreen.fontSizeY(), "MSP432 LP and CapTIvate BP");
myScreen.gText(0, myScreen.screenSizeY() - myScreen.fontSizeY(), "LCD_screen with Energia");
myScreen.setOrientation(1);
myScreen.setPenSolid(false);
for (uint8_t j = 0; j < 8; j++)
{
for (uint8_t i = 0; i < 8; i++)
{
myScreen.dRectangle(30 * i, 30 * j, 28, 28, whiteColour);
text = String(j * 8 + i + 1);
myScreen.gText(30 * i + 4 + (20 - myScreen.fontSizeX() * text.length()) / 2, 30 * j + 4 + (20 - myScreen.fontSizeY()) / 2, text, whiteColour);
}
}
myScreen.setPenSolid(true);
myScreen.setFontSolid(false);
}
void refreshScreen()
{
uint16_t colourRectangle = blackColour;
uint16_t colourText = whiteColour;
for (uint8_t j = 0; j < 8; j++)
{
for (uint8_t i = 0; i < 8; i++)
{
if (table[i][j] != oldTable[i][j])
{
text = String(j * 8 + i + 1);
switch (table[i][j])
{
case stateProximity:
colourRectangle = orangeColour;
colourText = blackColour;
break;
case stateTouch:
colourRectangle = greenColour;
colourText = blackColour;
break;
default:
colourRectangle = blackColour;
colourText = whiteColour;
break;
}
myScreen.dRectangle(30 * i + 4, 30 * j + 4, 20, 20, colourRectangle);
myScreen.gText(30 * i + 4 + (20 - myScreen.fontSizeX() * text.length()) / 2, 30 * j + 4 + (20 - myScreen.fontSizeY()) / 2, text, colourText);
}
}
}
memcpy(oldTable, table, sizeof(table));
}
// Add setup code
void setup()
{
Wire.begin();
pinMode(pinIRQ, INPUT);
pinMode(RED_LED, OUTPUT);
pinMode(pinSingleTouch, INPUT); // Single touch
pinMode(pinMultipleTouch, INPUT); // Multiple touch
prepareScreen();
}
// Add loop code
void loop()
{
getCapTIvate64();
refreshScreen();
}

点赞 2016-9-14 16:02

[经验] 【转载】Multi-Touch with CapTIvate

回复评论 （3）

沙发 maylove

板凳 maylove

4楼 maylove

回复评论（3）