2020年01月18日 | ARM启动代码的分析

估计以后会忘记，所以记下来。

一上电，硬件自动把NandFlash中的前4K数据拷贝进片内的SRAM。开始执行指令

@*************************************************************************

@ File：head.S

@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行

@*************************************************************************     

.equ        MEM_CTL_BASE,       0x48000000    @定义存储控制器的起始地址

.equ        SDRAM_BASE,         0x30000000       @定时SDRAM的起始地址

.text

.global _start

_start:

    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启，这是在SRAM中执行的。

    bl  memsetup                        @ 设置存储控制器，相对跳转指令，与程序处于片内或者片外无关，在SRAM中执行。

    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中，相对跳转指令，在SRAM中执行。

    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行，绝对跳转指令，会跳转到SDRAM中，在SRAM中执行。

在编译链接的时候，会在某个内存中保存（0x30000000+偏移地址）这个值，而偏移地址就是on_sdram的偏移地址。反汇编ldr pc,【pc，#144】， 当前pc+144就找到了这个内存，并把内存里面的值赋给pc，使pc指向了SDRAM。而0x3000000在Makefile中指定的。                                     

on_sdram:

    ldr sp, =0x34000000                 @ 设置堆栈。在SDRAM中执行的第一条指令

    bl  main                                      @跳转到main函数。

halt_loop:                                      @一直循环。

    b   halt_loop

@以下为子函数

disable_watch_dog:

    @ 往WATCHDOG寄存器写0即可

    mov r1,     #0x53000000

    mov r2,     #0x0

    str r2,     [r1]

    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:

    @ 将Steppingstone的4K数据全部复制到SDRAM中去

    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000

    mov r1, #0

    ldr r2, =SDRAM_BASE

    mov r3, #4*1024

1:  

    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4

    str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4

    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？

    bne 1b              @ 若没有复制完，继续

    mov pc,     lr      @ 返回

memsetup:

    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址

    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址

    add r3,     r1, #52             @ 13*4 = 54

1:  

    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4

    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4

    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器

    bne 1b                          @ 若没有写成，继续

    mov pc,     lr                  @ 返回

@以下为内存分配

.align 4

mem_cfg_val:

    @ 存储控制器13个寄存器的设置值

    .long   0x22011110      @ BWSCON

    .long   0x00000700      @ BANKCON0

    .long   0x00000700      @ BANKCON1

    .long   0x00000700      @ BANKCON2

    .long   0x00000700      @ BANKCON3  

    .long   0x00000700      @ BANKCON4

    .long   0x00000700      @ BANKCON5

    .long   0x00018005      @ BANKCON6

    .long   0x00018005      @ BANKCON7

    .long   0x008C07A3      @ REFRESH

    .long   0x000000B1      @ BANKSIZE

    .long   0x00000030      @ MRSRB6

    .long   0x00000030      @ MRSRB7