[资料分享] TI DSP定点算术运算之二

定点DSP芯片的数值表示是基于2的补码表示形式。每个16位数用1个符号位、i个整数位和15-i个小数位来表示。因此数00000010.10100000表示的值为 =2.625，这个数可用Q8格式(８个小数位)来表示，它表示的数值范围为-128~+127.996，一个Q8定点数的小数精度为1/256=0.004。

虽然特殊情况(如动态范围和精度要求)必须使用混合表示法，但是，更通常的是全部以Q15格式表示的小数或以Q0格式表示的整数来工作。这一点对于主要是乘法和累加的信号处理算法特别现实，小数乘以小数得小数，整数乘以整数得整数。当然，乘积累加时可能会出现溢出现象，在这种情况下，程序员应当了解数学里面的物理过程以注意可能的溢出情况。下面讨论乘法、加法和除法的DSP定点运算，汇编程序以TMS320C25为例。

2个定点数相乘时可以分为下列3种情况：

1．小数乘小数

Q15×Q15＝Q30

例3.9 0.5*0.5 = 0.25

0.100000000000000 ；Q15

× 0.100000000000000 ；Q15

00.010000000000000000000000000000=0.25 ；Q30

2个Q15的小数相乘后得到1个Q30的小数，即有2个符号位。一般情况下相乘后得到的满精度数不必全部保留，而只需保留16位单精度数。由于相乘后得到的高16位不满15位的小数精度，为了达到15位精度，可将乘积左移1位，下面是上述乘法的TMS320C25程序:

LT OP1 ；OP1=4000H(0.5/Q15)

MPY OP2 ；OP2=4000H(0.5/Q15)

PAC

SACH ANS,1 ；ANS=2000H(0.25/Q15)

2．整数乘整数

Q0×Q0 = Q0

例3.10 17×(-5)=-85

0000000000010001=17

× 1111111111111011=-5

11111111111111111111111110101011=-85

3．混合表示法

许多情况下，运算过程中为了既满足数值的动态范围又保证一定的精度，就必须采用Q0与Q15之间的表示法。比如，数值1.2345，显然Q15无法表示，而若用Q0表示，则最接近的数是1，精度无法保证。因此，数1.2345最佳的表示法是Q14。

例3.11 1.5×0.75 = 1.125

01.10000000000000 = 1.5 ；Q14

× 00.11000000000000 = 0.75 ；Q14

0001.0010000000000000000000000000 = 1.125;Q28

Q14的最大值不大于2，因此，2个Q14数相乘得到的乘积不大于4。

一般的，若一个数的整数位为 i位，小数位为 j 位，另一个数的整数位为 m 位，小数位为 n 位，则这两个数的乘积为 ( i + m )位整数位和(j + n)位小数位。这个乘积的最高16位可能的精度为( i + m )整数位和(15 - i - m)小数位。

但是，若事先了解数的动态范围，就可以增加数的精度。例如，程序员了解到上述乘积不会大于1.8，就可以用Q14数表示乘积，而不是理论上的最佳情况Q13。例3.11的TMS320C25程序如下：

LT OP1 ;OP1 = 6000H(1.5/Q14)

MPY OP2 ;OP2 = 3000H(0.75/Q14)

PAC

SACH ANS,1 ;ANS＝2400H(1.125/Q13)

上述方法为了保证精度均对乘的结果舍位，结果所产生的误差相当于减去1个LSB(最低位)。采用下面简单的舍入方法，可使误差减少二分之一。

LT OP1

MPY OP2

PAC

ADD ONE，14 (上舍入)

SACH ANS，1

上述程序说明，不管ANS为正或负，所产生的误差是1/2 LSB，其中存储单元ONE的值为1。

乘的过程中，程序员可不考虑溢出而只需调整运算中的小数点。而加法则是一个更加复杂的过程。首先，加法运算必须用相同的Q点表示；其次，程序员或者允许其结果有足够的高位以适应位的增长，或者必须准备解决溢出问题。如果操作数仅为16位长，其结果可用双精度数表示。下面举例说明16位数相加的两种途径。

1．保留32位结果

LAC OP1 ;(Q15)

ADD OP2 ;(Q15)

SACH ANSHI ;(高16位结果)

SACL ANSLO ;(低16位结果)

2．调整小数点保留16位结果

LAC OP1,15 ;(Q14数用ACCH表示)

ADD OP2,15 ;(Q14数用ACCH表示)

SACH ANS ;(Q14)

加法运算最可能出现的问题是运算结果溢出。TMS320提供了检查溢出的专用指令BV，此外，使用溢出保护功能可使累加结果溢出时累加器饱和为最大的整数或负数。当然，即使如此，运算精度还是大大降低。因此，最好的方法是完全理解基本的物理过程并注意选择数的表达方式。

在通用DSP芯片中，一般不提供单周期的除法指令，为此必须采用除法子程序来实现。二进制除法是乘法的逆运算。乘法包括一系列的移位和加法，而除法可分解为一系列的减法和移位。下面来说明除法的实现过程。

设累加器为8位，且除法运算为10除以3。除的过程就是除数逐步移位并与被除数比较的过程，在每一步进行减法运算，如果能减则将位插入商中。

(1) 除数的最低有效位对齐被除数的最高有效位。

00001010

－ 00011000

11110010

(2) 由于减法结果为负，放弃减法结果，将被除数左移一位再减。

00010100

－ 00011000

11111000

(3) 结果仍为负，放弃减法结果，被除数左移一位再减。

00101000

－ 00011000

00010000

(4) 结果为正，将减法结果左移一位后加１，作最后一次减。

00100001

－ 00011000

00001001

(5) 结果为正，将结果左移一位加1得最后结果。高４位代表余数，低4位表示商。

00010011

即商为0011=3，余数为0001=1。

TMS320没有专门的除法指令，但使用条件减指令SUBC可以完成有效灵活的除法功能。使用这一指令的唯一限制是两个操作数必须为正。程序员必须事先了解其可能的运算数的特性，如其商是否可以用小数表示及商的精度是否可被计算出来。这里每一种考虑可影响如何使用SUBC指令的问题。下面给出两种不同情况下的TMS320C25除法程序。

(1) 分子小于分母

DIV_A:

LT NUMERA

MPY DENOM

PAC

SACH TEMSGN ;取商的符号

LAC DENOM

ABS

SACL DENOM ;使分母为正

ZALH NUMERA ;使分子为正

ABS

RPTK 14

SUBC DENOM ;除循环15次

SACL QUOT

LAC TEMSGN

BGEZ A1 ;若符号为正,则完成

ZAC

SUB QUOT

SACL QUOT ;若为负,则商为负

A1: RET

这个程序中，分子在NUMERA中，分母在DENOM中，商存在QUOT中，TEMSGN为暂存单元。

(2) 规定商的精度

DIV_B:

LT NUMERA

MPY DENOM

PAC

SACH TEMSGN ;取商的符号

LAC DENOM

ABS

SACL DENOM ;使分母为正

LACK 15

ADD FRAC

SACL FRAC ;计算循环计数器

LAC NUMERA

ABS ;使分子为正

RPT FRAC

SUBC DENOM ;除循环16+FRAC次

SACL QUOT

LAC TEMSGN

BGEZ B1 ;若符号为正,则完成

ZAC

SUB QUOT

SACL QUOT ;若为负,则商为负

B1: RET

与DIV_A相同，这个程序中，分子在NUMERA中，分母在DENOM中，商存在QUOT中，TEMSGN为暂存单元。FRAC中规定商的精度，如商的精度为Q13，则调用程序前FRAC单元中的值应为13.