2018年04月15日 | ARM9的存储控制器

实验的目的：
把程序本身从Steppingstone复制到SDRAM处，然后跳转到SDRAM中执行

实验的源程序：
@*************************************************************************
@ File：head.S
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行
@*************************************************************************       

.equ        MEM_CTL_BASE,       0x48000000
.equ        SDRAM_BASE,         0x30000000

.text
.global _start
_start:
    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
    bl  memsetup                        @ 设置存储控制器
    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中
    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行
on_sdram:
    ldr sp, =0x34000000                 @ 设置堆栈
    bl  main
halt_loop:
    b   halt_loop

disable_watch_dog:
    @ 往WATCHDOG寄存器写0即可
    mov r1,     #0x53000000
    mov r2,     #0x0
    str r2,     [r1]
    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:
    @ 将Steppingstone的4K数据全部复制到SDRAM中去
    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000
    
    mov r1, #0
    ldr r2, =SDRAM_BASE
    mov r3, #4*1024
1:  
    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4
    str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？
    bne 1b              @ 若没有复制完，继续
    mov pc,     lr      @ 返回

memsetup:
    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址
    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址
    add r3,     r1, #52             @ 13*4 = 54
1:                                        @这是数值1，专业术语叫局部标号，主要用于bne 1b这条语句
    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器
    bne 1b                          @ 若没有写成，继续
    mov pc,     lr                  @ 返回

.align 4
mem_cfg_val:
    @ 存储控制器13个寄存器的设置值
    .long   0x22011110      @ BWSCON      @其实BWSCON这个寄存器的设置，主要是综合了存储控制器的其余BANK和外围器件的连接
    .long   0x00000700      @ BANKCON0   @一下这些寄存器的设置，都可以参考韦东山老师的书籍
    .long   0x00000700      @ BANKCON1
    .long   0x00000700      @ BANKCON2
    .long   0x00000700      @ BANKCON3  
    .long   0x00000700      @ BANKCON4
    .long   0x00000700      @ BANKCON5
    .long   0x00018005      @ BANKCON6
    .long   0x00018005      @ BANKCON7
    .long   0x008C07A3      @ REFRESH
    .long   0x000000B1      @ BANKSIZE
    .long   0x00000030      @ MRSRB6
    .long   0x00000030      @ MRSRB7

/**************************************************************************
led.c
**************************************************************************/

#define GPFCON (*(volatile unsigned long *)0x56000050)
#define GPFDAT (*(volatile unsigned long *)0x56000054)

#define GPF4_out (1<<(4*2))
#define GPF5_out (1<<(5*2))
#define GPF6_out (1<<(6*2))

void  wait(volatile unsigned long dly)
{
    for(; dly > 0; dly--);
}


int main(void)
{
    unsigned long i = 0;

    GPFCON = GPF4_out|GPF5_out|GPF6_out; // 将LED1,2,4对应的GPF4/5/6三个引脚设为输出

    while(1)
        {
            wait(30000);
            GPFDAT = (~(i<<4)); // 根据i的值，点亮LED1,2,4
            if(++i == 8)
            i = 0;
        }

    return 0;

}

/**************************************************************************
Makefile
**************************************************************************/

sdram.bin : head.S  leds.c
arm-linux-gcc  -c -o head.o head.S
arm-linux-gcc -c -o leds.o leds.c
arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
arm-linux-objcopy -O binary -S sdram_elf sdram.bin
arm-linux-objdump -D -m arm  sdram_elf > sdram.dis
clean:
rm -f   sdram.dis sdram.bin sdram_elf *.o

实验的问题总结：
I.在这期间，存储控制器起了一个什么作用？
在S3C2440/S3C2410中，对外引出的27根地址线ADDR0-ADDR26的访问范围只有128M，
CPU对外还引出了8根片选信号nGCS0-nGCS7，对应于BANK0-BANK7，当某一个片选信号拉低时，
对应的存储控制器的BANK就被选中，而每个BANK都是和外部设备相连的，当CPU发出某一地址信号时，
它会通过读取存储控制器的中的寄存器的配置信息，从而就知道了如何去访问外部的设备。我想这
大概就是存储控制器的作用。

II.存储控制器的BANK和SDRAM的Bank有什么区别？
存储控制器的BANK
在TQ2440中，存储控制器的BANK有8个，可以分别接8个不同的器件，通过片选信号使各个器件可以独立开来访问；
SDRAM的Bank
SDRAM的内部是一个存储阵列。阵列就如同那么表格一样，将数据“填”进去，你可以把它想象成一张表格。
和表格的检索原理一样，先指定一个行（Row），再指定一个列（Column），
我们就可以准确地找到所需要的单元格，这就是内存芯片寻址的基本原理。
对于内存，这个单元格可称为存储单元,那么这个表格（存储阵列）叫什么呢？
它就是逻辑 Bank（Logical Bank，下文简称L-Bank），所以说，准备的说SDRAM的Bank叫L-Bank

III.怎么确定SDRAM是接存储控制器的哪个BANK？还有就是每个BANK的对应的地址又是如何确定的？
关于SDRAM是接在存储控制器的哪个BANK上的，可以通过开发板的原理图的片选信号得知，因为片选信号和BANK是一一对应的；
当我们知道了SDRAM的是接在哪个BANK之后，接下来，我们如何知道这个SDRAM的地址呢？这主要是在S3C2440中的用户手册中
有介绍，对于每一个存储控制器的BANK，其地址都已经规定好了。

IV.既然在Makefile中，指定的链接地址是：0x3000 0000 ,那按理说这些代码段刚开始都是在SDRAM中执行的啊，而刚开始SDRAM
又没有初始化，这不矛盾么？
主要的原因是，在代码段中，bl  disable_watch_dog ，bl  memsetup ，bl  copy_steppingstone_to_sdram，因为都是相对跳转，所以说这些都是位置无关的几条指令，也就是说，这些代码即使不在链接时所指定的运行时地址空间，也可以正确执行，它是一段加载到任意地址空间都能正常执行的特殊代码。当程序运行到 ldr pc, =on_sdram 条指令的时候，由于是取on_sdram的绝对地址，而其地址标号是在SDRAM中的，所以说，执行完这条语句之后，程序就在SDRAM中运行了。关于这一点，可以百度一下位置无关代码的知识。


注：可参考的书籍《嵌入式Linux应用开发完全手册》